Amber16-bf3 for PRIMERGY | Research Center for Computational Science

Webpage

http://ambermd.org/

Version

Amber 16 bugfix 3 + AmberTools 16 bugfix 7

Tools for Compiling

Intel Compiler 16.0.2.181
Intel MPI 5.1.3
Intel MKL 2016.2.181
NVIDIA CUDA 7.5
Python 2.7

Necessary Files for Compiling

Amber16.tar.bz2
AmberTools16.tar.bz2
Patches in http://ambermd.org/bugfixes16.html
Patches in http://ambermd.org/bugfixesat.html

Procedure of Compiling

#!/bin/csh -f
umask 022
# Working directory must be installed directory to work with mpi4py.
set work="/local/apl/pg/amber16-bf3"
set build="/home/users/${USER}/build/amber16-bf3"
setenv AMBERHOME "$work"
setenv CUDA_HOME /usr/local/cuda-7.5
setenv LD_LIBRARY_PATH "${CUDA_HOME}/lib64:${LD_LIBRARY_PATH}:${AMBERHOME}/lib"
setenv MKL_HOME ${MKLROOT}
# Setup for python-2.7
setenv PATH /opt/rh/python27/root/usr/bin:${PATH}
setenv LD_LIBRARY_PATH /opt/rh/python27/root/usr/lib64:${LD_LIBRARY_PATH}
setenv XDG_DATA_DIRS /opt/rh/python27/root/usr/share
setenv PKG_CONFIG_PATH /opt/rh/python27/root/usr/lib64/pkgconfig
# Installed directory must be created by builder.
if (-e $AMBERHOME/configure) then
echo "Remove $AMBERHOME to be clean."
exit 1
endif
if (! -d $AMBERHOME) then
echo "Create $AMBERHOME before build."
exit 1
endif
cd $AMBERHOME
bunzip2 -c ${build}/Amber16.tar.bz2 | tar xf -
bunzip2 -c ${build}/AmberTools16.tar.bz2 | tar xf -
mv amber16/* .
rmdir amber16
#
# Apply patches if they exist.
#
foreach i (${build}/patches/Amber16 ${build}/patches/AmberTools16)
foreach j ($i/*.? $i/*.??)
patch -p0 < $j
end
end
#
echo "[GPU (SPFP) serial edition]"
./configure --no-updates -cuda gnu
make -j 12 install
make clean
echo "[GPU (SPFP) parallel edition]"
./configure --no-updates -mpi -cuda gnu
make -j 12 install
make clean

echo "[GPU (DPFP) serial edition]"
./configure --no-updates -cuda_DPFP gnu
make -j 12 install
make clean
echo "[GPU (DPFP) parallel edition]"
./configure --no-updates -mpi -cuda_DPFP gnu
make -j 12 install
make clean

# LANG must be C to get correct a compiler version.
setenv LANG C
# Environment variable SSE_TYPES is insignificant.
echo "[CPU serial edition]"
./configure --no-updates intel
make -j 12 install
source $AMBERHOME/amber.csh
make test
make clean
echo "[CPU parallel edition]"
setenv DO_PARALLEL "mpirun.actual -np 4"
./configure --no-updates -intelmpi intel
make -j 12 install
mpdboot
make test
mpdallexit
make clean
#
cd $AMBERHOME
chmod 700 src

View PDF