You are here

Amber12-bf21 for PRIMERGY

Webpage

http://ambermd.org/

Version

Amber 12 bugfix 21 + AmberTools 13 bugfix 20

Tools for Compiling

  • Intel Compiler 11.1.080 (Cannot work in version 12 or higher.)
  • Intel MPI 4.1.0.030 (Cannot compile in version 4.0.2.)

Necessary Files for Compiling

Procedure of Compiling

#!/bin/csh -f
#PBS -l select=ncpus=16:mpiprocs=16:ompthreads=1:jobtype=gpu
#PBS -l walltime=72:00:00
if ($?PBS_O_WORKDIR) then
cd ${PBS_O_WORKDIR}
endif
umask 022
# Directory for installation must be the same as working directory. Otherwise, mpi4py cannot work.
set work="/local/apl/pg/amber12-bf21"
set build="/home/users/${USER}/build/amber12"
setenv AMBERHOME "$work"
setenv CUDA_HOME /usr/local/cuda
# Delete old files.
if (-e $AMBERHOME/configure) then
echo "Remove $AMBERHOME to be clean."
exit 1
endif
if (! -d $AMBERHOME) then
echo "Create $AMBERHOME before build."
exit 1
endif
# Make sure that "mpd" is running.
setenv DO_PARALLEL "mpirun -np 2"
#
cd $AMBERHOME
bunzip2 -c ${build}/Amber12.tar.bz2 | tar xf -
bunzip2 -c ${build}/AmberTools13.tar.bz2 | tar xf -
mv amber12/* .
#
foreach i (${build}/patches/AmberTools13 ${build}/patches/Amber12)
foreach j ($i/*.? $i/*.??)
patch -p0 < $j
end
end
#
echo "[GPU (SPDP) serial edition]"
./configure --no-updates -cuda gnu
make -j 16 install
make test.cuda
make clean
echo "[GPU (SPDP) parallel edition]"
./configure --no-updates -mpi -cuda gnu
make -j 16 install
make clean

echo "[GPU (SPSP) serial edition]"
./configure --no-updates -cuda_SPSP gnu
make -j 16 install
cd $AMBERHOME/test/
./test_amber_cuda.sh SPSP
cd $AMBERHOME
make clean
echo "[GPU (SPSP) parallel edition]"
./configure --no-updates -mpi -cuda_SPSP gnu
make -j 16 install
make clean

echo "[GPU (DPDP) serial edition]"
./configure --no-updates -cuda_DPDP gnu
make -j 16 install
cd $AMBERHOME/test/
./test_amber_cuda.sh DPDP
cd $AMBERHOME
make clean
echo "[GPU (DPDP) parallel edition]"
./configure --no-updates -mpi -cuda_DPDP gnu
make -j 16 install
make clean
# To get compiler version correctly, set LANG environment value.
setenv LANG C
# SSE_TYPES environment value means option "-ax${SSE_TYPES}", so unset it.
unsetenv SSE_TYPES
# If you use intel compiler version 12,
#     rism1d will be aborted and test of MPI fail.
source /opt/intel/Compiler/11.1/080/bin/iccvars.csh intel64
source /opt/intel/Compiler/11.1/080/bin/ifortvars.csh intel64
# Use intel compilers in mpicc, mpicxx and mpif90.
setenv I_MPI_CC icc
setenv I_MPI_CXX icpc
setenv I_MPI_F90 ifort
#
echo "[CPU serial edition]"
./configure --no-updates intel
make -j 16 install
make test
make clean
echo "[CPU parallel edition]"
./configure --no-updates -mpi intel
make -j 16 install
make test